home *** CD-ROM | disk | FTP | other *** search
/ Experimental BBS Explossion 3 / Experimental BBS Explossion III.iso / graphics / pov2doc.zip / CHARS.INC < prev    next >
Text File  |  1993-07-19  |  16KB  |  656 lines
  1. #declare Chars_Inc_Temp=version
  2. #version 2.0
  3.  
  4. // CHARS.INC R2.0
  5. // Characters for POV-RAY V2.0
  6. // An including file.
  7. // Original by Ken Maeno 1992-93
  8. // Revised and extended by Chris Young
  9. //
  10. // This file includes 26 upper-case letter and other characters defined 
  11. // as objects. The size of all characters is 4 * 5 * 1. The center of the 
  12. // bottom side of a character face is set to the origin, so please 
  13. // translate a character appropriately before rotating it about 
  14. // the x or z axes.
  15. //     Usage:
  16. //
  17. //     object{ 
  18. //       char_A
  19. //      pigment{ color Red }
  20. //    }
  21. //
  22.  
  23. #declare char_A = 
  24.  intersection {
  25.    box{<-2,0,-0.1>,<2,5,1.1>}
  26.    union { 
  27.      box{<-0.5,-6,0>,<0.5,0,1> rotate  z*16.699 }
  28.      box{<-0.5,-6,0>,<0.5,0,1> rotate -z*16.699 }
  29.      box{<-1,  -4,0>,<1, -3,1> }
  30.      translate y*5
  31.    }
  32.    bounded_by{ box { <-2,0,0>,<2,5,1> } }
  33.  }
  34.  
  35. #declare char_P = 
  36.   union {
  37.     difference{
  38.       cylinder{0*z,z,1.5}
  39.       cylinder{-z,2*z,0.5}
  40.       plane{x,0}
  41.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  42.       translate<0.5, 3.5, 0>
  43.     }
  44.     box{ <-1, 4, 0>, <0.5, 5, 1> }
  45.     box{ <-1, 2, 0>, <0.5, 3, 1> }
  46.     box{ <-2, 0, 0>, <-1, 5, 1 > }
  47.   }
  48.  
  49. #declare char_B = 
  50.   union {
  51.     object{char_P}
  52.     difference{
  53.       cylinder{0*z,z,1.5}
  54.       cylinder{-z,2*z,0.5}
  55.       plane{x,0}
  56.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  57.       translate<0.5, 1.5, 0>
  58.     }
  59.     box{ <-1, 0, 0>, <0.5, 1, 1> }
  60.   }
  61.  
  62. #declare char_C = 
  63.   union {
  64.     difference{
  65.       cylinder{0*z,z,2}
  66.       cylinder{-z,2*z,1}
  67.       plane{y,0}
  68.       bounded_by{ box { <-2,0,0>, <2,2,1> } }
  69.       translate 3*y
  70.     }
  71.     difference{
  72.       cylinder{0*z,z,2}
  73.       cylinder{-z,2*z,1}
  74.       plane{-y,0}
  75.       bounded_by{ box { <-2,-2,0>, <2,0,1> } }
  76.       translate 2*y
  77.     }
  78.     box{ <-2,2,0>,<-1,3,1> }
  79.   }
  80.  
  81. #declare char_D = 
  82.   union {
  83.     difference{
  84.       cylinder{0*z,z,2.5}
  85.       cylinder{-z,2*z,1.5}
  86.       plane{x,0}
  87.       bounded_by{ box { <0,-2.5,0>, <2.5,2.5,1> } }
  88.       translate <-0.5,2.5,0>
  89.     }
  90.     box{ <-1,4,0>,<-0.5,5,1> }
  91.     box{ <-1,0,0>,<-0.5,1,1> }
  92.     box{ <-2,0,0>,<-1,  5,1> }
  93.   }
  94.  
  95. #declare char_F = 
  96.   union {
  97.     box{ <-2,0,0>,<-1,5,1> }
  98.     box{ <-1,2,0>,<1.5,3,1> }
  99.     box{ <-1,4,0>,<2,5,1> }
  100.   }
  101.  
  102. #declare char_E = 
  103.   union {
  104.     object{char_F}
  105.     box{ <-1,0,0>,<2,1,1> }
  106.   }
  107.  
  108. #declare char_G = 
  109.   union {
  110.     object{char_C}
  111.     box{ < 0,1.5,0>,<2,2.3,1> }
  112.   }
  113.  
  114. #declare char_H = 
  115.   union {
  116.     box{ <-2,0,0>,<-1,5,1> }
  117.     box{ < 1,0,0>,< 2,5,1> }
  118.     box{ <-1,2,0>,< 1,3,1> }
  119.   }
  120.  
  121. #declare char_I = 
  122.   box{ <-0.5,0,0>,<0.5,5,1> }
  123.  
  124. #declare char_J = 
  125.   union {
  126.     difference{
  127.       cylinder{0*z,z,2}
  128.       cylinder{-z,2*z,1}
  129.       plane{-y,0}
  130.       bounded_by{ box { <-2,-2,0>, <2,0,1> } }
  131.       translate 2*y
  132.     }
  133.     box{ <1,2,0>,<2,5,1> }
  134.   }
  135.  
  136. #declare char_K = 
  137.   union {
  138.     intersection {
  139.       union {
  140.         box{ <0,-2,0>,<0.9,5,1> rotate z*45  translate x*0.7272 }
  141.         box{ <0,-5,0>,<0.9,2,1> rotate -z*45 translate <0.7272,5,0> }
  142.       }
  143.       box { <-1,0,-0.1>,<2,5,1.1> }
  144.       bounded_by{ box { <-2,0,0>,<2,5,1> } }
  145.     }
  146.     box { <-2,0,0>,<-1,5,1> }
  147.   }
  148.  
  149. #declare char_L = 
  150.    union {
  151.      box{ <-2,1,0>,<-1,5,1> }
  152.      box{ <-2,0,0>,<2,1,1>  }
  153.    }
  154.  
  155. #declare char_M = 
  156.   union {
  157.     intersection{
  158.       union {
  159.         box{<-0.5,-1,0>,<0.5,5,1> rotate  z*26.5651}
  160.         box{<-0.5,-1,0>,<0.5,5,1> rotate -z*26.5651}
  161.       }
  162.       box{<-1,0,-0.1>,<1,3,1.1>}
  163.       bounded_by{box{<-2,0,0>,<2,4,1>}}
  164.       translate y*2
  165.     }
  166.     box{ <-2,0,0>,<-1,5,1> }
  167.     box{ < 1,0,0>,< 2,5,1> }
  168.   }
  169.  
  170. #declare char_N = 
  171.   union {
  172.     intersection{
  173.       box{ <0,0,0>,<1,6,1> rotate z*32.5031 translate x}
  174.       box{ <-1,0,-0.1>,<1,5,1.1> }
  175.       bounded_by{box{ <-1,0,0>,<1,5,1> } }
  176.     }
  177.     box{ <-2,0,0>,<-1,5,1> }
  178.     box{ <1,0,0>,<2,5,1> }
  179.   }
  180.  
  181. #declare char_O = 
  182.   union {
  183.     object {char_C}
  184.     box{ <1,2,0>,<2,3,1> }
  185.   }
  186.  
  187. #declare char_Q = 
  188.   union {
  189.     object {char_O}
  190.     box{ <0,0,0>,<1,2.2,1> rotate z*45 translate x*1.29289}
  191.   }
  192.  
  193. #declare char_R = 
  194.   union {
  195.     object {char_P}
  196.     intersection {
  197.       box{ <0,-2,0>,<1,5,1> rotate z*36.8699 translate x}
  198.       box{ <-1,0,-0.1>,<2,2,1.1> }
  199.       bounded_by{box{ <-1,0,0>,<2,2,1> }}
  200.     }
  201.   }
  202.  
  203. #declare char_S = 
  204.   union {
  205.     intersection{
  206.       cylinder{0*z,z,1.5}
  207.       cylinder{-z,2*z,0.5 inverse}
  208.       box{<0,0,-0.1>,<1.5,1.5,1.1>}
  209.       bounded_by{ box { <0,0,0>, <1.5, 1.5, 1> } }
  210.       translate <0.5,3.5,0>
  211.     }
  212.     difference{
  213.       cylinder{0*z,z,1.5}
  214.       cylinder{-z,2*z,0.5}
  215.       plane{x,0}
  216.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  217.       translate<0.5, 1.5, 0>
  218.     }
  219.     intersection{
  220.       cylinder{0*z,z,1.5}
  221.       cylinder{-z,2*z,0.5 inverse}
  222.       box{<-1.5,-1.5,-0.1>,<0,0,1.1>}
  223.       bounded_by{ box { <-1.5,-1.5,0>, <0, 0, 1> } }
  224.       translate <-0.5,1.5,0>
  225.     }
  226.     difference{
  227.       cylinder{0*z,z,1.5}
  228.       cylinder{-z,2*z,0.5}
  229.       plane{-x,0}
  230.       bounded_by{ box { <-1.5,-1.5,0>, <0, 1.5, 1> } }
  231.       translate<-0.5, 3.5, 0>
  232.     }
  233.     box{ <-0.5,4,0>,<0.5,5,1> }
  234.     box{ <-0.5,2,0>,<0.5,3,1> }
  235.     box{ <-0.5,0,0>,<0.5,1,1> }
  236.   }
  237.  
  238. #declare char_T = 
  239.   union{
  240.     box{ <-0.5,0,0>,<0.5,4,1> }
  241.     box{ <-2,  4,0>,<  2,5,1> }
  242.   }
  243.  
  244. #declare char_U = 
  245.   union {
  246.     object{char_J}
  247.     box{ <-2,2,0>,<-1,5,1> }
  248.   }
  249.  
  250. #declare char_V = 
  251.   intersection {
  252.     box{<-2,0,-0.1>,<2,5,1.1>}
  253.     union { 
  254.       box{<-0.5,-1,0>,<0.5,6,1> rotate  z*16.699 }
  255.       box{<-0.5,-1,0>,<0.5,6,1> rotate -z*16.699 }
  256.     }
  257.    bounded_by{ box { <-2,0,0>,<2,5,1> } }
  258.  }
  259.  
  260. #declare char_W = 
  261.   union {
  262.     intersection{
  263.       union {
  264.         box{<-0.5,-5,0>,<0.5,0,1> rotate  z*26.5651}
  265.         box{<-0.5,-5,0>,<0.5,0,1> rotate -z*26.5651}
  266.         translate 3*y
  267.       }
  268.       box{<-1,0,-0.1>,<1,3,1.1>}
  269.       bounded_by{box{<-1,0,0>,<2,3,1>}}
  270.     }
  271.     box{ <-2,0,0>,<-1,5,1> }
  272.     box{ < 1,0,0>,< 2,5,1> }
  273.   }
  274.  
  275. #declare char_X = 
  276.   intersection {
  277.     box{<-2,0,-0.1>,<2,5,1.1>}
  278.     union {
  279.       box{<-0.5,-3.5,0>,<0.5,3.5,1> rotate  z*30.9}
  280.       box{<-0.5,-3.5,0>,<0.5,3.5,1> rotate -z*30.9}
  281.       translate 2.5*y
  282.     }
  283.     bounded_by{ box { <-2,0,0>,<2,5,1> } }
  284.  }
  285.  
  286. #declare char_Y = 
  287.   union {
  288.     intersection {
  289.       box{<-2,2,-0.1>,<2,5,1.1>}
  290.       union {
  291.         box{<-0.5,0,0>,<0.5,3.5,1> rotate  z*30.9}
  292.         box{<-0.5,0,0>,<0.5,3.5,1> rotate -z*30.9}
  293.         translate 2.5*y
  294.       }
  295.       bounded_by{ box { <-2,2,0>,<2,5,1> } }
  296.     }
  297.     box {<-0.5,0,0>,<0.5,3,1>}
  298.  }
  299.  
  300. #declare char_Z = 
  301.   union {
  302.     intersection{
  303.       box{ <0,0,0>,<1,7,1> rotate z*-29.6749 translate -2*x}
  304.       box{<-2,0,-0.1>,<2,5,1.1>}
  305.       bounded_by{ box { <-2,0,0>,<2,5,1> } }
  306.     }
  307.     box{ <-2,4,0>,<1.2,5,1> }
  308.     box{ <-1.2,0,0>,<2,1,1> }
  309.   }
  310.  
  311. #declare char_Dash = 
  312.    box{ <-2,2,0>,<2,3,1> }
  313.  
  314. #declare char_Plus = 
  315.    union{
  316.      box{ <-2,2,0>,<2,3,1> }
  317.      box{ <-0.5,0.5,0>,<0.5,4.5,1> }
  318.    }
  319.  
  320. #declare char_0 = object{char_O}
  321.  
  322. #declare char_1 = 
  323.    union{
  324.      object{char_I}
  325.      box{ <0,-1.25,0>,<1,0,1> rotate -z*45 translate <-0.5,5,0>}
  326.      box{ <-1,0,0>,<1,1,1> }
  327.    }
  328.  
  329. #declare char_2 = 
  330.   union{
  331.     intersection{
  332.       cylinder{0*z,z,1.5}
  333.       cylinder{-z,2*z,0.5 inverse}
  334.       box{<-1.5,0,-0.1>,<0,1.5,1.1>}
  335.       bounded_by{ box { <-1.5,0,0>, <0, 1.5, 1> } }
  336.       translate<-0.5, 3.5, 0>
  337.     }
  338.     intersection{
  339.       cylinder{0*z,z,1.5}
  340.       cylinder{-z,2*z,0.5 inverse}
  341.       plane{-x,0 }
  342.       plane{-y,0 rotate -z*54 }
  343.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  344.       translate <0.5,3.5,0>
  345.     }
  346.     box{<-0.5,4,0>,<0.5,5,1>}
  347.     box{<-2,0,0>,<2,1,1>}
  348.     box{< 0,0.5,0>,<3.5,1.5,1> rotate -z*(90+54) translate <0.5,3.5,0>}
  349.   }
  350.  
  351. #declare char_3 = 
  352.   union {
  353.     intersection{
  354.       cylinder{0*z,z,1.5}
  355.       cylinder{-z,2*z,0.5 inverse}
  356.       box{<-1.5,0,-0.1>,<0,1.5,1.1>}
  357.       bounded_by{ box { <-1.5,0,0>, <0, 1.5, 1> } }
  358.       translate<-0.5, 3.5, 0>
  359.     }
  360.     difference{
  361.       cylinder{0*z,z,1.5}
  362.       cylinder{-z,2*z,0.5}
  363.       plane{x,0}
  364.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  365.       translate<0.5, 3.5, 0>
  366.     }
  367.     difference{
  368.       cylinder{0*z,z,1.5}
  369.       cylinder{-z,2*z,0.5}
  370.       plane{x,0}
  371.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  372.       translate<0.5, 1.5, 0>
  373.     }
  374.     intersection{
  375.       cylinder{0*z,z,1.5}
  376.       cylinder{-z,2*z,0.5 inverse}
  377.       box{<-1.5,-1.5,-0.1>,<0,0,1.1>}
  378.       bounded_by{ box { <-1.5,-1.5,0>, <0, 0, 1> } }
  379.       translate <-0.5,1.5,0>
  380.     }
  381.     box{ <-0.5,4,0>,<0.5,5,1> }
  382.     box{ <-0.5,2,0>,<0.5,3,1> }
  383.     box{ <-0.5,0,0>,<0.5,1,1> }
  384.   }
  385.  
  386. #declare char_4 = 
  387.   union {
  388.     box {<0,0,0>,<1,5,1>}
  389.     box {<-2,1,0>,<2,2,1>}
  390.     box {<0,-1,0>,<3.6,0,1> rotate z*56.31 translate <-2,2,0>}
  391.   }
  392.  
  393. #declare char_5 = 
  394.   union {
  395.     difference{
  396.       cylinder{0*z,z,1.5}
  397.       cylinder{-z,2*z,0.5}
  398.       plane{x,0}
  399.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  400.       translate<0.5, 1.5, 0>
  401.     }
  402.     intersection{
  403.       cylinder{0*z,z,1.5}
  404.       cylinder{-z,2*z,0.5 inverse}
  405.       box{<-1.5,-1.5,-0.1>,<0,0,1.1>}
  406.       bounded_by{ box { <-1.5,-1.5,0>, <0, 0, 1> } }
  407.       translate <-0.5,1.5,0>
  408.     }
  409.     box{ <-1,4,0>,<2,5,1> }
  410.     box{ <-2,2,0>,<-1,5,1> }
  411.     box{ <-1,2,0>,<0.5,3,1> }
  412.     box{ <-0.5,0,0>,<0.5,1,1> }
  413.   }
  414.  
  415. #declare char_6 = 
  416.   union {
  417.     intersection{
  418.       cylinder{0*z,z,1.5}
  419.       cylinder{-z,2*z,0.5 inverse}
  420.       box{<0,0,-0.1>,<1.5,1.5,1.1>}
  421.       bounded_by{ box { <0,0,0>, <1.5, 1.5, 1> } }
  422.       translate <0.5,3.5,0>
  423.     }
  424.     intersection{
  425.       cylinder{0*z,z,1.5}
  426.       cylinder{-z,2*z,0.5 inverse}
  427.       box{<-1.5,0,-0.1>,<0,1.5,1.1>}
  428.       bounded_by{ box { <-1.5,0,0>, <0,1.5,1> } }
  429.       translate<-0.5, 3.5, 0>
  430.     }
  431.     difference{
  432.       cylinder{0*z,z,1.5}
  433.       cylinder{-z,2*z,0.5}
  434.       plane{x,0}
  435.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  436.       translate<0.5, 1.5, 0>
  437.     }
  438.     difference{
  439.       cylinder{0*z,z,1.5}
  440.       cylinder{-z,2*z,0.5}
  441.       plane{-x,0}
  442.       bounded_by{ box { <-1.5,-1.5,0>, <0, 1.5, 1> } }
  443.       translate <-0.5,1.5,0>
  444.     }
  445.     box{ <-0.5,4,0>,<0.5,5,1> }
  446.     box{ <-2,1.5,0>,<-1,3.5,1> }
  447.     box{ <-0.5,2,0>,<0.5,3,1> }
  448.     box{ <-0.5,0,0>,<0.5,1,1> }
  449.   }
  450.  
  451. #declare char_7 = 
  452.   union{
  453.     box{ <-2,  4,0>,<  2,5,1> }
  454.     intersection {
  455.       box{ <-1,-1,0>,<0,4.272,1> rotate -z*20.556 translate x/2}
  456.       box{<-0.5,0,-0.1>,<2,4.5,1.1>}
  457.       bounded_by{box{<-0.5,0,-0>,<2,4.5,1>}}
  458.     }
  459.   }
  460.  
  461. #declare char_8 = 
  462.   union {
  463.     difference{
  464.       cylinder{0*z,z,1.5}
  465.       cylinder{-z,2*z,0.5}
  466.       plane{-x,0}
  467.       bounded_by{ box { <-1.5,-1.5,0>, <0, 1.5, 1> } }
  468.       translate<-0.5, 3.5, 0>
  469.     }
  470.     difference{
  471.       cylinder{0*z,z,1.5}
  472.       cylinder{-z,2*z,0.5}
  473.       plane{x,0}
  474.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  475.       translate<0.5, 3.5, 0>
  476.     }
  477.     difference{
  478.       cylinder{0*z,z,1.5}
  479.       cylinder{-z,2*z,0.5}
  480.       plane{x,0}
  481.       bounded_by{ box { <0,-1.5,0>, <1.5, 1.5, 1> } }
  482.       translate<0.5, 1.5, 0>
  483.     }
  484.     difference{
  485.       cylinder{0*z,z,1.5}
  486.       cylinder{-z,2*z,0.5}
  487.       plane{-x,0}
  488.       bounded_by{ box { <-1.5,-1.5,0>, <0, 1.5, 1> } }
  489.       translate <-0.5,1.5,0>
  490.     }
  491.     box{ <-0.5,4,0>,<0.5,5,1> }
  492.     box{ <-0.5,2,0>,<0.5,3,1> }
  493.     box{ <-0.5,0,0>,<0.5,1,1> }
  494.   }
  495.  
  496. #declare char_9 = 
  497.   object{char_6 translate -2.5*y rotate z*180 translate 2.5*y}
  498.  
  499. #declare char_ExclPt=
  500.   union {
  501.     cylinder {<0,4.5,0>,<0,4.5,1>,0.5}
  502.     cylinder {<0,0.5,0>,<0,0.5,1>,0.5}
  503.     intersection {
  504.       box{<-0.5,-3,0>,<0.5,0,1> rotate  z*9.5}
  505.       box{<-0.5,-3,-0.1>,<0.5,0,1.1> rotate -z*9.5 }
  506.       bounded_by{box{<-0.5,-3,0>,<0.5,0,1> }}
  507.       translate y*4.5
  508.     }
  509.   }
  510.  
  511. #declare char_AtSign = 
  512.   union {
  513.     difference{
  514.       cylinder{0*z,z,2}
  515.       cylinder{-z,2*z,1.5}
  516.       box { <0,-1.25,-0.1>, <2.5,0,1.1> } 
  517.       bounded_by{ box { <-2,-2,0>, <2,2,1> } }
  518.       translate 2.5*y
  519.     }
  520.     difference{
  521.       cylinder{0*z,z,0.75}
  522.       cylinder{-z,2*z,0.25}
  523.       plane{-y,0}
  524.       bounded_by{ box { <-2,-2,0>, <2,0,1> } }
  525.       translate <1.25,2.5,0>
  526.     }
  527.     difference{
  528.       cylinder{0*z,z,1}
  529.       cylinder{-z,2*z,0.5}
  530.       bounded_by{ box { <-1,-1,0>, <1,1,1> } }
  531.       translate 2.5*y
  532.     }
  533.   }
  534.  
  535. #declare char_Num = 
  536.   union {
  537.     box{ <-0.5,-2,0>,<0.5,2,1> rotate -10*z translate <-1,2.5,0>}
  538.     box{ <-0.5,-2,0>,<0.5,2,1> rotate -10*z translate < 1,2.5,0>}
  539.     box{ <-1.5,3,0>,< 2,4,1> }
  540.     box{ <-2,1,0>,< 1.5,2,1> }
  541.   }
  542.  
  543. #declare char_Dol = 
  544.   union {
  545.     difference{
  546.       cylinder{0*z,z,1.25}
  547.       cylinder{-z,2*z,0.25}
  548.       plane{x,0}
  549.       bounded_by{ box { <0,-1.25,0>, <1.25, 1.25, 1> } }
  550.       translate<0.75, 1.75, 0>
  551.     }
  552.     difference{
  553.       cylinder{0*z,z,1.25}
  554.       cylinder{-z,2*z,0.25}
  555.       plane{-x,0}
  556.       bounded_by{ box { <-1.25,-1.25,0>, <0, 1.25, 1> } }
  557.       translate<-0.75, 3.25, 0>
  558.     }
  559.     box{ <-0.75,3.5,0>,<2,4.5,1> }
  560.     box{ <-0.75,2,0>,<0.75,3,1> }
  561.     box{ <-2,0.5,0>,<0.75,1.5,1> }
  562.     box{ <-0.5,0,0>,<0.5,5,1> }
  563.   }
  564.  
  565. #declare char_Perc = 
  566.   union {
  567.     difference{
  568.       cylinder{0*z,z,1}
  569.       cylinder{-z,2*z,0.25}
  570.       bounded_by{ box { <-1,-1,0>, <1, 1, 1> } }
  571.       translate<1, 1, 0>
  572.     }
  573.     difference{
  574.       cylinder{0*z,z,1}
  575.       cylinder{-z,2*z,0.25}
  576.       bounded_by{ box { <-1,-1,0>, <1, 1, 1> } }
  577.       translate<-1, 4, 0>
  578.     }
  579.     box{ <-0.25,-2.8,0>,<0.25,2.8,1> rotate -33*z translate 2.5*y}
  580.   }
  581.  
  582. #declare char_Hat = 
  583.   intersection {
  584.     union {
  585.       box{ <0,0,0>,<1,3,1>  rotate -33*z translate <-2,1.5,0>}
  586.       box{ <-1,0,0>,<0,3,1> rotate  33*z translate < 2,1.5,0>}
  587.     }
  588.     box {<-2.1,1.5,-0.1>,<2.1,3.75,1.1>}
  589.     bounded_by{box {<-2.1,1.5,0>,<2.1,3.75,1>}}
  590.   }
  591.  
  592. #declare char_Amps = 
  593.   union {
  594.     difference{
  595.       cylinder{0*z,z,1.25}
  596.       cylinder{-z,2*z,0.5}
  597.       bounded_by{ box { <-1.25,-1.25,0>, <1.25, 1.25, 1> } }
  598.       translate <-0.25,3.75,0>
  599.     }
  600.     difference{
  601.       cylinder{0*z,z,1.75}
  602.       cylinder{-z,2*z,0.75}
  603.       bounded_by{ box { <-1.75,-1.75,0>, <1.75, 1.75, 1> } }
  604.       translate <-0.25,1.75,0>
  605.     }
  606.     difference{
  607.       cylinder{0*z,z,1.25}
  608.       cylinder{-z,2*z,0.5}
  609.       plane{-x,0}
  610.       bounded_by{ box { <-1.25,-1.25,0>, <0, 1.25, 1> } }
  611.       translate <2,1.75,0>
  612.     }
  613.   }
  614.  
  615. #declare char_Astr = 
  616.   union {
  617.     box{ <-0.5,-2,0>,<0.5,2,1> }
  618.     box{ <-0.5,-2,0>,<0.5,2,1> rotate 60*z}
  619.     box{ <-0.5,-2,0>,<0.5,2,1> rotate -60*z}
  620.     translate 2.5*y
  621.   }
  622.  
  623. #declare char_LPar = 
  624.   intersection{
  625.     cylinder{<7,2.5,0>,<7,2.5,1>, 7.5}
  626.     cylinder{<7,2.5,-0.1>,<7,2.5,1.1>, 6.5 inverse}
  627.     box{<-2,0,-0.1>,<2,5,1.1>}
  628.     bounded_by{box{<-1,0,0>,<1,5,1>}}
  629.   }
  630.  
  631. #declare char_RPar = 
  632.   intersection{
  633.     cylinder{<-7,2.5,0>,<-7,2.5,1>, 7.5}
  634.     cylinder{<-7,2.5,-0.1>,<-7,2.5,1.1>, 6.5 inverse}
  635.     box{<-2,0,-0.1>,<2,5,1.1>}
  636.     bounded_by{box{<-1,0,0>,<1,5,1>}}
  637.   }
  638.  
  639. #declare char_LSqu =
  640.   union {
  641.     box{<-1,0,0>,<0,5,1>}
  642.     box{<0,0,0>,<1,1,1>}
  643.     box{<0,4,0>,<1,5,1>}
  644.   }
  645.  
  646. #declare char_RSqu =
  647.   union {
  648.     box{<0,0,0>,<1,5,1>}
  649.     box{<-1,0,0>,<0,1,1>}
  650.     box{<-1,4,0>,<0,5,1>}
  651.   }
  652.  
  653.  
  654. // End of CHARS.INC
  655. #version Chars_Inc_Temp
  656.